Buy

Function Syntax

boolean buy(item it ,int qty )

• it is the item to purchase
• qty is the (optional) number to purchase

int buy(item it ,int qty ,int price )

• it is the item to purchase
• qty is the number to purchase
• price is the (optional) maximum price to spend per item

boolean buy(int qty ,item it )

• qty is the number to purchase
• it is the item to purchase

int buy(int qty ,item it ,int price )

• qty is the number to purchase
• it is the item to purchase
• price is the (optional) maximum price to spend per item

boolean buy(coinmaster master ,int qty ,item it )

• master is the coinmaster to purchase from
• qty is the number to purchase
• it is the item to purchase

Attempts to purchase qty amount of item it. (Will not buy using meat from storage; use buy_using_storage() instead.) If qty is less than 1, the function will return true without purchasing anything. If the optional maximum price is specified, it returns the integer amount of items purchased; otherwise it returns true if the purchase succeeded and false if it did not. If a price less than 1 is passed, the function will always buy qty, regardless of price. Without the optional price parameter, first preference is given to NPC stores when attempting purchases, after which it will attempt to use the mall.

The versions that return a boolean value determine success depending on whether your inventory of the desired item went up by the amount you tried to buy.

If a coinmaster is listed, it will attempt to purchase from the coinmaster using the correct alternate currency. Otherwise it will be purchased from an NPC store or mall using meat.

Code Sample

Buy a broken skull.

buy(1 , $item[broken skull]);

This expands upon purchasing from a coinmaster to show many related functions.

boolean buy_coinmaster(int qty, item it) {
   coinmaster master = it.seller;
   if(master == $coinmaster[none]) {
      print("You do not need a coinmaster to purchase that", "red");
      return false;
   }
   if(!is_accessible(master)) {
      print(inaccessible_reason(master), "red");
      return false;
   }
   int coins = master.available_tokens;
   int price = sell_price(master, it);
   if(price > coins) {
      print("You only have "+coins+" "+master.token+", but it costs "+price+" "+master.token, "red");
      return false;
   }
   return buy(master, qty, it);
}

CLI Equivalent

The CLI commands "buy" and "acquire" work similarly.

See Also

sell() | buy_price() | buy_using_storage()